Funkcia IF v Exceli: podmienka vo vzorci
IF otestuje podmienku a podľa výsledku vráti jednu z dvoch hodnôt, napríklad „splnené“ alebo „nesplnené“. Naučíš sa napísať podmienku, vrátiť text, číslo aj výpočet a opraviť najčastejšie chyby.
Vyskúšaj si to: Stačí rozpočet?
Do bunky B4 napíš =IF(B2>B1;"prekročený";"v poriadku") a stlač Enter. Keď je minuté viac ako rozpočet, ukáže sa „prekročený“, inak „v poriadku“.
| A | B | |
|---|---|---|
| 1 | Rozpočet (€) | 500 |
| 2 | Minuté (€) | 430 |
| 3 | ||
| 4 | Rozpočet je |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =IF(B2>B1;"prekročený";"v poriadku")
Podmienka B2>B1 platí, keď je minuté viac ako rozpočet. Vtedy IF vráti prvý text, inak druhý. Pri 430 € z 500 € je rozpočet „v poriadku“.
Ako funguje funkcia IF
=IF(logický_test; hodnota_ak_pravda; [hodnota_ak_nepravda])
- logický_test: podmienka, ktorá platí alebo neplatí, napríklad
B2>=50. - hodnota_ak_pravda: čo vráti, keď podmienka platí.
- hodnota_ak_nepravda: čo vráti, keď podmienka neplatí. Je nepovinná, ale keď ju vynecháš, IF v takom prípade ukáže FALSE.
Aj v slovenskom Exceli sa funkcia volá IF a argumenty oddeľuje bodkočiarka. Vzorec sa dá čítať ako veta: „ak platí podmienka, tak toto, inak tamto“.
Porovnávacie znaky
=rovná sa,<>nerovná sa;>väčšie ako,<menšie ako;>=väčšie alebo rovné,<=menšie alebo rovné.
Pri slovách „od“ a „aspoň“ použi >=, pri „nad“ >. Rozdiel sa prejaví len pri
hraničnej hodnote, a práve tam sa chyba najľahšie prehliadne. Porovnávať môžeš bunku s číslom, dve bunky
alebo výsledok inej funkcie, napríklad SUM(B2:B5)<=B7.
Text, číslo alebo výpočet vo výsledku
Text vo výsledku daj do úvodzoviek: "áno". Čísla píš bez úvodzoviek, inak z nich bude text, ktorý
napríklad SUM pri sčítaní preskočí. Výsledkom môže byť aj výpočet, napríklad B2*0,9. Dve úvodzovky za sebou
"" znamenajú prázdny text, bunka potom vyzerá prázdna.
Príklady
Porovnanie s textom
Stály zákazník má zľavu 10 %. Keď je v B1 „áno“, IF vráti cenu zníženú o desatinu, inak plnú cenu.
=IF(B1="áno";B2*0,9;B2) | A | B | |
|---|---|---|
| 1 | Stály zákazník | áno |
| 2 | Cena (€) | 80 |
| 3 | ||
| 4 | Na úhradu (€) | 72 |
Pri porovnaní textu Excel nerozlišuje veľké a malé písmená, „Áno“ a „áno“ sú rovnaké.
Je bunka prázdna?
Faktúra nemá vyplnený dátum úhrady. Podmienka B2="" platí, keď je bunka prázdna.
=IF(B2="";"neuhradená";"uhradená") | A | B | |
|---|---|---|
| 1 | Faktúra | F-118 |
| 2 | Uhradená dňa | |
| 3 | ||
| 4 | Stav | neuhradená |
Funkcia v podmienke
Kurz sa hodnotí ako úspešný, keď je priemerné hodnotenie aspoň 4,5 bodu z 5.
=IF(AVERAGE(B2:B4)>=4,5;"úspešný";"treba zlepšiť") | A | B | |
|---|---|---|
| 1 | Účastník | Hodnotenie |
| 2 | Lea | 5 |
| 3 | Rastislav | 4 |
| 4 | Dominika | 5 |
| 5 | ||
| 6 | Kurz | úspešný |
Časté chyby a čo znamenajú
Chyba #NAME?
Text vo vzorci nie je v úvodzovkách. =IF(B2>B1;prekročený;"v poriadku") hľadá názov
„prekročený“, nenájde ho a vráti #NAME?. Rovnako to dopadne pri preklepe v názve funkcie.
Vo výsledku je FALSE
Chýba tretí argument. Keď podmienka neplatí a IF nemá čo vrátiť, ukáže FALSE. Doplň bodkočiarku a za ňu
hodnotu, napríklad 0 alebo "".
Číslo vo výsledku sa nesčíta
Výsledok "0" v úvodzovkách je text. SUM ho preskočí a bunka je zarovnaná vľavo. Čísla vo
výsledku IF píš bez úvodzoviek.
Hraničná hodnota vyjde zle
Pri objednávke presne za 50 € s podmienkou B1>50 doprava zadarmo nebude. Over si vzorec
vždy aj s hodnotou rovnou hranici. Znak = píš až za < alebo >, teda >=, nie =>.
Cvičenia
Päť úloh od ľahkých po náročnejšie. Vzorec píš do vyznačenej bunky, kontrolu spustíš klávesom Enter alebo tlačidlom Skontrolovať. Kontrola vzorec vyskúša aj na iných číslach vrátane hraničných.
Cvičenie 1: Doprava zadarmo
ľahkáE-shop s čajmi dáva dopravu zadarmo pri objednávke od 50 €. Inak stojí 3,90 €. Do bunky B3 napíš vzorec, ktorý podľa sumy v B1 vráti cenu dopravy.
| A | B | |
|---|---|---|
| 1 | Objednávka (€) | 38,50 |
| 2 | ||
| 3 | Doprava (€) |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =IF(B1>=50;0;3,9)
B1>=50 platí aj pri objednávke presne za 50 €. Vtedy IF vráti 0, inak 3,9. Čísla vo výsledku sú bez úvodzoviek, aby sa s nimi dalo ďalej počítať.
Cvičenie 2: Čo treba objednať
ľahkáKancelária sleduje zásoby. Keď je na sklade menej kusov ako minimum, treba objednať. Do D2 napíš vzorec, ktorý vráti text „objednať“, inak „dosť“. Vzorec sa skopíruje do D3 až D5.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Tovar | Sklad | Minimum | Stav |
| 2 | Papier A4 | 3 | 5 | |
| 3 | Perá | 40 | 20 | |
| 4 | Toner | 1 | 2 | |
| 5 | Zošívačky | 6 | 4 |
Klikni na bunku a jej adresa sa vloží do vzorca. Bunky s prerušovaným okrajom ukážu, čo vzorec vypočíta po skopírovaní.
Riešenie: =IF(B2<C2;"objednať";"dosť")
Vzorec v D2 porovná B2 s C2. Po skopírovaní sa odkazy posunú, takže D3 porovnáva B3 s C3 a tak ďalej. Pri rovnakom počte ako minimum ešte objednávať netreba.
Cvičenie 3: Príplatok za nadčas
strednáIvana má mesačný fond 160 hodín. Za každú hodinu navyše dostane príplatok z bunky B3. Do B5 napíš vzorec, ktorý vypočíta príplatok za nadčas. Keď nadčas nemá, má vyjsť 0.
| A | B | |
|---|---|---|
| 1 | Odpracované hodiny | 172 |
| 2 | Fond hodín | 160 |
| 3 | Príplatok za hodinu (€) | 6,50 |
| 4 | ||
| 5 | Príplatok spolu (€) |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =IF(B1>B2;(B1-B2)*B3;0)
Keď je B1 viac ako B2, IF vypočíta (B1-B2)*B3, teda 12 hodín krát 6,50 €. Inak vráti 0. Bez IF by pri menej hodinách vyšiel záporný príplatok.
Cvičenie 4: Výlet v rozpočte
strednáTrieda plánuje výlet do Vysokých Tatier. Do B8 napíš vzorec, ktorý sčíta náklady v B2 až B5 a porovná ich s rozpočtom v B7. Keď súčet nie je vyšší ako rozpočet, vráti „v rozpočte“, inak „prekročený“.
| A | B | |
|---|---|---|
| 1 | Položka | Suma (€) |
| 2 | Autobus | 620 |
| 3 | Ubytovanie | 1150 |
| 4 | Strava | 480 |
| 5 | Vstupné | 210 |
| 6 | ||
| 7 | Rozpočet (€) | 2600 |
| 8 | Stav |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =IF(SUM(B2:B5)<=B7;"v rozpočte";"prekročený")
SUM(B2:B5) dá 2 460 €, to je menej ako 2 600 €, takže podmienka platí. Pri súčte presne 2 460 € a rozpočte 2 460 € je výlet ešte v rozpočte, preto <=.
Cvičenie 5: Odmena za splnený cieľ
náročnejšiaPredajcovia dostanú odmenu, keď tržba dosiahne aspoň cieľ v B8. Odmena je toľko percent z tržby, koľko je v B9. Do C2 napíš vzorec, ktorý vypočíta odmenu, inak vráti 0. Vzorec sa skopíruje do C3 až C6.
| A | B | C | |
|---|---|---|---|
| 1 | Predajca | Tržba (€) | Odmena (€) |
| 2 | Bielik | 5400 | |
| 3 | Gregorová | 4750 | |
| 4 | Hudec | 6120 | |
| 5 | Mináriková | 5000 | |
| 6 | Polák | 3980 | |
| 7 | |||
| 8 | Cieľ (€) | 5000 | |
| 9 | Odmena (%) | 5% |
Klikni na bunku a jej adresa sa vloží do vzorca. Bunky s prerušovaným okrajom ukážu, čo vzorec vypočíta po skopírovaní.
Riešenie: =IF(B2>=$B$8;B2*$B$9;0)
V =IF(B2>=$B$8;B2*$B$9;0) sa pri kopírovaní mení len B2 na B3, B4… Cieľ $B$8 a percento $B$9 zostanú. Mináriková má tržbu presne 5 000 €, cieľ splnila, preto >=.
Otázky a odpovede
Ako napísať podmienku v Exceli?
Funkciou IF: =IF(podmienka;ak platí;ak neplatí). Napríklad =IF(B2>=50;"prospel";"neprospel")
vráti „prospel“, keď je v B2 aspoň 50. Na zafarbenie buniek podľa podmienky slúži podmienené formátovanie.
Ako sa píše funkcia IF v slovenskom Exceli?
Rovnako ako v anglickom, len s bodkočiarkami: =IF(B2>B1;"áno";"nie"). České KDYŽ v slovenskom
Exceli nefunguje a desatinné čísla píšeš s čiarkou, napríklad 3,9.
Ako dať do IF viac podmienok?
Keď majú platiť všetky naraz, použi v podmienke funkciu AND, keď stačí jedna, funkciu OR. Pri viacerých pásmach, napríklad známkach, sa hodí IFS alebo IF vnorené do seba. Všetko je na stránke IF s viacerými podmienkami.
Ako nechať bunku prázdnu, keď podmienka neplatí?
Ako tretí argument daj dve úvodzovky: =IF(B2>0;B2*C2;""). Bunka bude vyzerať prázdna, ale
vzorec v nej zostane.